• 回答数

    0

  • 浏览数

    1534

  • 收藏数

    0

作者:阿贤懂科研 发表于 2022-1-17 09:52:25
跳转到指定楼层
1
案例背景
压电晶片梁由两个连在一起极性相反的压电层组成。压电双晶片广泛应用于驱动和感应领域。在驱动领域,将压电双晶片应用于穿过梁的电场,当一层变大时另外一层将缩小。这将引起整个结构和末端挠度的弯曲变形。在遥感领域,通过控制电极电压引起的压电, 压电双晶片可以测量外部载荷。
图1中给出了压电双晶片梁的示意图, 晶片上表面有10个相同的电极块, 晶片下表面是接地的。对驱动的模拟可以采用线性静态分析,在上表面施加100V的电压,可以确定梁端部的变形;对感应的模拟可以采用大挠度静力分析,在梁端部施加10mm的挠度,可以确定电极电压。

图1:压电双晶片梁示意图
其中, L = 100mm ;H=0. 5mm 。
材料属性见下表。


2
操作演示




3
模型结果图片


4
APDL代码
!定义工作标题
/title, Static Analysis of a Piezoelectric Bimorph Beam
/nopr

!预处理
/PREP7

! 定义问题参数
!
! 几何参数
L=100e-3
H=0.5e-3
!
!  载荷参数
V=100  
Uy=10.e-3
!
!   材料属性
E1=2.0e9  
NU12=0.29  
G12=0.775e9  
d31=2.2e-11  
d32=0.3e-11
d33=-3.0e-11
ept33=12
!
! 创建模型
local,11  
local,12,,,,,180  
csys,11   
rect,0,L,-H,0   
rect,0,L, 0,H   
aglue,all   
esize,H  

!定义单元类型
et,1,PLANE223,1001,,0  


tb,ANEL,1,,,1
tbda,1,1/E1,-NU12/E1,-NU12/E1
tbda,7,1/E1,-NU12/E1
tbda,12,1/E1
tbda,16,1/G12

tb,PIEZ,1,,,1  
tbda,2,d31
tbda,5,d33
tbda,8,d32

tb,DPER,1,,,1  
tbdata,1,ept33,ept33

tblist,all   

!划分网格
type,1 $ esys,11
amesh,1  
type,1 $ esys,12            
amesh,3   

!设置边界条件
nsel,s,loc,x,L                  
*get,ntip,node,0,num,min
!
nelec = 10   
*dim,ntop,array,nelec
l1 = 0   
l2 = L/nelec           
*do,i,1,nelec   
nsel,s,loc,y,H               
nsel,r,loc,x,l1,l2
cp,i,volt,all
*get,ntop(i),node,0,num,min   
l1 = l2 + H/10   
l2 = l2 + L/nelec
*enddo
nsel,s,loc,y,-H  
d,all,volt,0   
nsel,s,loc,x,0   
d,all,ux,0,,,,uy
nsel,all
fini

!求解
/SOLU  
antype,static
*do,i,1,nelec
d,ntop(i),volt,V
*enddo
solve

!理论求解
Uy_an = -3*d31*V*L**2/(8*H**2)  
fini

!求解
/SOLU   
antype,static,new
*do,i,1,nelec
ddele,ntop(i),volt   
*enddo
d,ntip,uy,Uy     
nlgeom,on   
nsubs,2     
cnvtol,F,1.e-3,1.e-3      
cnvtol,CHRG,1.e-8,1.e-3     
!cnvtol,AMPS,1.e-8,1.e-3      
solve
fini

!后处理
/POST1

*do,i,1,nelec
*enddo

/view,,1,,1  
/dscale,1,1   
pldisp,1  
path,position,2,,100   
ppath,1,,0,H        
ppath,2,,L,H
pdef,Volt,volt,,noav   
pdef,Uy,u,y   
/axlab,x, Position (m)
/axlab,y, Electrode Voltage (Volt)
plpath,Volt  
/axlab,y, Beam Deflection (m)
plpath,Uy   
fini

本帖子中包含更多资源

您需要 登录 才可以下载或查看,没有帐号?立即注册 微信登录

x
分享:
回复

使用道具

成为第一个回答人

高级模式 评论
您需要登录后才可以回帖 登录 | 立即注册 微信登录
关于作者
阿贤懂科研

用户组:版主

  • 主题

    16

  • 帖子

    16

  • 关注者

    0